
    BoxTurtle

A toolkit of Elixir building blocks:
	Schema: a convention-driven Ecto data-access layer. You get get, list, count, create, update and delete for a schema, with filters, sorting, pagination and preloads, in two lines of code.
	Runtime: typed, validated configuration from environment variables, runtime config scripts, and configurable module dispatch (handy for Mox).
	Debug: a pipe-friendly debug/3 that you turn on per module through config.
	Common / Security: result-tuple helpers, ID generators, and a secure password generator.

Installation
Add box_turtle to your dependencies in mix.exs:
def deps do
  [
    {:box_turtle, "~> 0.1"}
  ]
end
BoxTurtle requires Elixir 1.20 or later. The Schema modules work with any Ecto SQL adapter. :distinct on lists uses DISTINCT ON, which is PostgreSQL-only. With SQLite, MySQL or MSSQL it raises an ArgumentError: at compile time for :default_distinct, and when the query is built for call-time :distinct. Counts can use :distinct with any adapter.
Schema in two minutes
Given an ordinary Ecto schema with a changeset/2, in an application with an Ecto repo MyApp.Repo:
defmodule MyApp.Blog.Post do
  use Ecto.Schema
  import Ecto.Changeset

  schema "posts" do
    field :title, :string
    field :status, :string, default: "draft"
    field :likes, :integer, default: 0
    timestamps()
  end

  def changeset(post, attrs) do
    post |> cast(attrs, [:title, :status, :likes]) |> validate_required([:title])
  end
end
add a Query module and a Change module next to it:
defmodule MyApp.Blog.Post.Query do
  # Newest first; the id breaks ties between rows inserted in the same second.
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, default_sort: [desc: :inserted_at, desc: :id]
end

defmodule MyApp.Blog.Post.Change do
  use BoxTurtle.Schema.Change, repo: MyApp.Repo
end
and use them (starting from an empty posts table):
alias MyApp.Blog.Post

{:ok, hello} = Post.Change.create(%{title: "Hello"})
{:ok, _} = Post.Change.create(%{title: "Popular", status: "published", likes: 40})
{:ok, _} = Post.Change.create(%{title: "Also out", status: "published", likes: 3})
{:error, %Ecto.Changeset{}} = Post.Change.create(%{title: nil})

{:ok, hello} = Post.Change.update(hello, %{status: "published"})
{:ok, %Post{title: "Hello"}} = Post.Query.get(hello.id)
{:error, :not_found} = Post.Query.get(-1)

Post.Query.list!(filters: [status: "published"], sort: [desc: :likes]) |> Enum.map(& &1.title)
#=> ["Popular", "Also out", "Hello"]

Post.Query.list!(page: [number: 2, size: 2]) |> Enum.map(& &1.title)
#=> ["Hello"]

Post.Query.count!()                      #=> 3
Post.Query.count!(group_by: [:status])   #=> [%{status: "published", count: 3}]

{:ok, _deleted} = Post.Change.delete(hello.id)
The schema is inferred from the module name (MyApp.Blog.Post.Query serves MyApp.Blog.Post). The Schema guide is a complete walkthrough that adds associations and single-query join preloads, custom filters and sorts, and pattern-scoped list_by/2 functions with shared delegates.
Runtime configuration
BoxTurtle.Runtime.Config.Helper.get_env/2 reads an environment variable, parses it into the type you want and validates it:
# config/runtime.exs
import Config
alias BoxTurtle.Runtime.Config.Helper

config :my_app,
  # POOL_SIZE=20 -> 20; unset -> 10; POOL_SIZE=500 -> {:error, "value 500 not in specified range 1..100"}
  pool_size: Helper.get_env("POOL_SIZE", type: :integer, default: 10, in_range: 1..100),
  # HOSTS="a.example.com, b.example.com" -> ["a.example.com", "b.example.com"]
  hosts: Helper.get_env("HOSTS", type: :list, default: ["localhost"]),
  # LOG_LEVEL=debug -> :debug (must be an existing atom in the set)
  log_level: Helper.get_env("LOG_LEVEL", type: :atom, in_set: [:debug, :info, :warning], default: :info),
  # FEATURES='{"beta": true}' -> %{"beta" => true}
  features: Helper.get_env("FEATURES", type: :map, default: %{})
Supported types: :string, :integer, :float, :boolean, :atom, :module, :charlist, :list, :tuple and :map (JSON). Lists and tuples can have typed elements (subtype:). Atoms and modules must already exist, unless you pass unsafe_atoms: true. Invalid values come back as {:error, message}. With a validation and no :default, an unset variable is an error too.
BoxTurtle.Runtime.Config.load_runtime_config/1 loads a separate import Config script (from any path, e.g. beside a release) into the application environment at runtime. BoxTurtle.Runtime.Application.Helper.conditional_append/4 builds supervision trees whose children depend on a condition. Both modules' docs show complete setups.
Module dispatch
Put a stable facade in front of a configurable implementation:
# The contract (compiled before the facade).
defmodule MyApp.Mailer.API do
  @callback deliver(to :: String.t(), subject :: String.t()) :: {:ok, term()} | {:error, term()}
end

# The default implementation, found by the <facade>.Impl naming convention.
defmodule MyApp.Mailer.Impl do
  @behaviour MyApp.Mailer.API

  @impl true
  def deliver(to, subject), do: MyApp.SmtpClient.send(to, subject)
end

# The facade: implements MyApp.Mailer.API by forwarding each call to MyApp.Mailer.Impl,
# or to whatever `config :my_app, MyApp.Mailer, impl: ...` names.
defmodule MyApp.Mailer do
  use BoxTurtle.Runtime.DynamicInterface.ModuleDispatch, otp_app: :my_app
end

# Callers only know the facade.
defmodule MyApp.Accounts do
  def send_welcome(user), do: MyApp.Mailer.deliver(user.email, "Welcome!")
end
Tests swap in a Mox mock through config:
# test/test_helper.exs
Mox.defmock(MyApp.Mailer.Mock, for: MyApp.Mailer.API)

# config/test.exs
config :my_app, MyApp.Mailer, impl: MyApp.Mailer.Mock

# test/my_app/accounts_test.exs
defmodule MyApp.AccountsTest do
  use ExUnit.Case, async: true
  import Mox

  setup :verify_on_exit!

  test "send_welcome/1 mails the user" do
    expect(MyApp.Mailer.Mock, :deliver, fn "ann@example.com", "Welcome!" -> {:ok, :sent} end)
    assert {:ok, :sent} = MyApp.Accounts.send_welcome(%{email: "ann@example.com"})
  end
end
The implementation is read on every call. So the same facade gives you a different implementation per build, runtime switching (failover, feature flags), Mox mocks that can fall back to a real implementation, and A/B tests through a router implementation. All of these are demonstrated, with fake implementations, in test/support/examples/dispatch.ex and its tests.
Pipe debugging
defmodule MyApp.Billing do
  use BoxTurtle.Debug.PipeDebug

  def total(order) do
    order.items
    |> Enum.map(& &1.price)
    |> debug("prices")
    |> Enum.sum()
  end
end
# config/dev.exs: only these modules log, at :debug level
config :my_app, debug_enabled_modules: [MyApp.Billing]
config :logger, level: :debug
MyApp.Billing.total(%{items: [%{price: 5}, %{price: 7}]}) returns 12 and logs prices: [5, 7]. In builds where MyApp.Billing isn't listed, the debug/2 calls stay in the code and log nothing.
Utilities
	BoxTurtle.Common.ReturnOkOr.return_ok_or/2: nil, bare values, :error → {:ok, _} / {:error, reason}.
	BoxTurtle.Common.IdUtils: KSUID and UUID generators.
	BoxTurtle.Schema.Ecto.Ksuid: a KSUID Ecto.Type for primary keys.
	BoxTurtle.Security.Password.generate/1: random passwords from a cryptographically secure source, always containing lowercase, uppercase, digit and special characters.

Development
mix deps.get
mix test            # Schema tests run against SQLite; no database server needed

# Also run the PostgreSQL-only tests (DISTINCT ON); the database is created and dropped for you
BOX_TURTLE_PG_URL=postgres://postgres:postgres@localhost:5432/box_turtle_test mix test
mix credo --strict
mix dialyzer
mix docs

License
MIT. See LICENSE.


  

    Changelog

All notable changes to this project are documented here. The format follows
Keep a Changelog, and the project uses
Semantic Versioning.
0.1.0 - 2026-11-02
First public release.
Added
	BoxTurtle.Schema.Query and BoxTurtle.Schema.Change: generated read and write functions for Ecto schemas, with filters, sorting, pagination, preloads, grouping, distinct and pattern-scoped *_by extensions (extend/2, delegate/1).
	BoxTurtle.Schema.Filters and BoxTurtle.Schema.Sort: working defaults plus use bases for custom clauses. Filters support nil (IS NULL) and lists (IN).
	BoxTurtle.Schema.Pagination: page: n or page: [number: n, size: s], with a per-module :page_size.
	BoxTurtle.Schema.Ecto.Ksuid: a KSUID Ecto.Type.
	BoxTurtle.Runtime.Config.Helper: the :map type (JSON, via the standard library) and the unsafe_atoms option.
	BoxTurtle.Runtime.DynamicInterface.ModuleDispatch: facade modules that forward a behaviour to a configurable implementation, or generate stubs.
	BoxTurtle.Security.Password.min_length/0.
	:distinct with an adapter that has no DISTINCT ON (SQLite3, MyXQL, Tds) raises a clear ArgumentError when the query is built. A :default_distinct like that is rejected at compile time.

Changed (compared to the pre-release code)
	:atom and :module config values must name existing atoms unless unsafe_atoms: true is given.
	Runtime.Config reads scripts with Elixir's Config.Reader; the external_config dependency is gone.
	Security.Password uses a cryptographically secure random source and returns {:error, :too_short}. It also now honours the requested length; previously some lengths produced shorter passwords.
	Schema.Query.get/2 returns {:error, :not_found} when no row matches.
	count/1 uses COUNT(*) and no longer requires an inserted_at column.
	The :no_defaults option is now :ignore_defaults.
	:preloads are loaded with LEFT JOINs in the same query instead of one query per association. With to-many preloads, paging and distinct are applied to parent rows through a primary-key subquery. Preload queries and functions are no longer accepted.

Fixed
	count(group_by: ["column"]) with string column names crashed while building the select.
	Config.Helper.get_env/2 crashed for an unset variable with a non-string :type and no :default; it now returns nil.

Removed
	Application.Helper.conditional_applications/3,4, conditional_modules/3,4 and conditional_children/3,4. Use conditional_append/3,4.
	Schema.Change.create/2, and the placeholder *_by functions (generate them with extend/2 or delegate/1).
	Dependencies on poison, hackney, sweet_xml, cloak_ecto, earmark, atomic_map, jason and external_config.



  

    Schema guide

BoxTurtle.Schema gives every Ecto schema the same small data-access API. Callers use it instead of building queries and calling the Repo themselves.
This guide builds a small blog step by step. Every snippet is complete, and later snippets show each module in full as it grows. Run them in order in iex -S mix and you'll get the results shown. The guide assumes an application :my_app with an Ecto repo MyApp.Repo.
1. Schemas and migration
BoxTurtle works with plain Ecto schemas. The only requirement is a changeset function for writes (changeset/2 by default).
defmodule MyApp.Blog.Author do
  use Ecto.Schema
  import Ecto.Changeset

  schema "authors" do
    field :name, :string
    has_many :posts, MyApp.Blog.Post
    timestamps()
  end

  def changeset(author, attrs) do
    author |> cast(attrs, [:name]) |> validate_required([:name])
  end
end

defmodule MyApp.Blog.Post do
  use Ecto.Schema
  import Ecto.Changeset

  schema "posts" do
    field :title, :string
    field :status, :string, default: "draft"
    field :likes, :integer, default: 0
    belongs_to :author, MyApp.Blog.Author
    timestamps()
  end

  # Used for inserts.
  def changeset(post, attrs) do
    post
    |> cast(attrs, [:title, :status, :likes, :author_id])
    |> validate_required([:title])
  end

  # Used for updates: only the status may change after creation.
  def update_changeset(post, attrs) do
    post
    |> cast(attrs, [:status])
    |> validate_inclusion(:status, ~w(draft published archived))
  end
end
# priv/repo/migrations/20260101000000_create_blog.exs
defmodule MyApp.Repo.Migrations.CreateBlog do
  use Ecto.Migration

  def change do
    create table(:authors) do
      add :name, :string, null: false
      timestamps()
    end

    create table(:posts) do
      add :title, :string, null: false
      add :status, :string, null: false, default: "draft"
      add :likes, :integer, null: false, default: 0
      add :author_id, references(:authors, on_delete: :delete_all)
      timestamps()
    end

    create index(:posts, [:author_id])
  end
end
2. Query and Change modules
Put the modules inside the schema's namespace. The schema is then inferred: MyApp.Blog.Post.Query serves MyApp.Blog.Post. If yours live elsewhere, pass schema: explicitly.
defmodule MyApp.Blog.Author.Query do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, default_sort: [:name, :id]
end

defmodule MyApp.Blog.Author.Change do
  use BoxTurtle.Schema.Change, repo: MyApp.Repo
end

defmodule MyApp.Blog.Post.Query do
  # Newest first; the id breaks ties between rows inserted in the same second.
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, default_sort: [desc: :inserted_at, desc: :id]
end

defmodule MyApp.Blog.Post.Change do
  use BoxTurtle.Schema.Change, repo: MyApp.Repo, update_changeset: :update_changeset
end
All use options are documented in BoxTurtle.Schema.Query and BoxTurtle.Schema.Change.
3. Writing
alias MyApp.Blog.{Author, Post}

{:ok, ann} = Author.Change.create(%{name: "Ann"})
{:ok, bob} = Author.Change.create(%{name: "Bob"})

{:ok, hello} = Post.Change.create(%{title: "Hello", author_id: ann.id})
{:ok, _second} = Post.Change.create(%{title: "Second post", likes: 12, author_id: ann.id})
{:ok, _news} = Post.Change.create(%{title: "Bob's news", status: "published", likes: 5, author_id: bob.id})
{:ok, scratch} = Post.Change.create(%{title: "Scratch"})

# changeset/2 requires a title
{:error, %Ecto.Changeset{}} = Post.Change.create(%{})

# Updates go through update_changeset/2
{:ok, hello} = Post.Change.update(hello, %{status: "published"})
{:error, %Ecto.Changeset{}} = Post.Change.update(hello, %{status: "deleted"})

# Delete a struct, a changeset or a primary key
{:ok, _} = Post.Change.delete(scratch)
{:error, :not_found} = Post.Change.delete(scratch.id)
create/1 and update/1 also accept a ready-made Ecto.Changeset. create!/1, update!/2 and delete!/1 return the struct or raise; delete!/1 raises Ecto.NoResultsError for a missing key.
The blog now has three posts:
	title	status	likes	author
	Hello	published	0	Ann
	Second post	draft	12	Ann
	Bob's news	published	5	Bob

4. Reading
Every function has a tuple form and a ! form:
{:ok, %Post{title: "Hello"}} = Post.Query.get(hello.id)
{:error, :not_found} = Post.Query.get(-1)
nil = Post.Query.get!(-1)
%Post{likes: 12} = Post.Query.get!(%{title: "Second post"})   # look up by other columns

Post.Query.list!() |> Enum.map(& &1.title)
#=> ["Bob's news", "Second post", "Hello"]   (newest first)

Post.Query.list!(filters: [status: "published"], sort: [:title]) |> Enum.map(& &1.title)
#=> ["Bob's news", "Hello"]

Post.Query.count!()                          #=> 3
Post.Query.count!(group_by: [:status])       #=> [%{status: "draft", count: 1}, %{status: "published", count: 2}]
Post.Query.count!(distinct: [:author_id])    #=> 2

# An Ecto.Query, not run yet, to compose further or run yourself
query = Post.Query.query!(filters: [author_id: ann.id])
2 = query |> MyApp.Repo.all() |> length()
Call-time options (all of them are listed in BoxTurtle.Schema.Query.API):
	Option	Example	Meaning
	:filters	[status: "draft", author_id: nil]	WHERE, see below
	:sort	[desc: :likes, asc: :id]	ORDER BY, replaces the default sort
	:page	2 or [number: 2, size: 10]	LIMIT/OFFSET
	:preloads	[author: :posts]	associations, LEFT JOINed and loaded in the same query
	:group_by	[:status]	count returns one map per group
	:distinct	[:author_id]	DISTINCT ON for lists (PostgreSQL only; other adapters raise ArgumentError), COUNT(DISTINCT ...) for counts on any adapter
	:ignore_defaults	true	skip the module's default sort, preloads and distinct

Filters
Default filters compare columns:
Post.Query.count!(filters: [status: "published"])                # status = 'published'       => 2
Post.Query.count!(filters: [status: ["draft", "published"]])     # status IN (...)            => 3
Post.Query.count!(filters: [author_id: nil])                     # author_id IS NULL          => 0
Post.Query.count!(filters: [{"status", "draft"}])                # string key, existing atom  => 1
String keys are converted with String.to_existing_atom/1, so filters built from request params can't create new atoms. Still, only pass column names you allow. Any column of the schema is filterable.
For anything other than equality, write a filter module. Each clause handles the filter at the head of the list and must pass the rest back to filter_with/2. Filters your clauses don't match fall through to the defaults:
defmodule MyApp.Blog.Post.Filters do
  use BoxTurtle.Schema.Filters
  import Ecto.Query

  def filter_with(query, [{:min_likes, likes} | rest]) do
    query
    |> where([p], p.likes >= ^likes)
    |> filter_with(rest)
  end
end

defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query,
    repo: MyApp.Repo,
    default_sort: [desc: :inserted_at, desc: :id],
    filter_module: MyApp.Blog.Post.Filters
end
Post.Query.list!(filters: [status: "published", min_likes: 1]) |> Enum.map(& &1.title)
#=> ["Bob's news"]
Custom clauses see keys exactly as given, so match atoms and convert request params yourself.
Sorting
A sort spec is a list of columns, {direction, column} pairs, or {direction, [columns]}. Keyword lists work as-is: [desc: :inserted_at, asc: :id]. Named sorts work like filters:
defmodule MyApp.Blog.Post.Sort do
  use BoxTurtle.Schema.Sort
  import Ecto.Query

  # Most liked first; the id keeps the order stable for pagination.
  def sort_by(query, [:popularity | rest]) do
    query
    |> order_by([p], desc: p.likes, asc: p.id)
    |> sort_by(rest)
  end
end

defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query,
    repo: MyApp.Repo,
    default_sort: [desc: :inserted_at, desc: :id],
    filter_module: MyApp.Blog.Post.Filters,
    sorting_module: MyApp.Blog.Post.Sort
end
Post.Query.list!(sort: [:popularity]) |> Enum.map(& &1.title)
#=> ["Second post", "Bob's news", "Hello"]
An unknown sort element raises ArgumentError.
Preloads
Preloads are fetched with LEFT JOINs, so a list or get, together with all its associations, is a single round trip to the database. Ecto's plain preload issues one extra query per association. Nesting works to any depth:
[%Post{author: %Author{name: "Bob"}} | _] = Post.Query.list!(preloads: [:author])

Author.Query.list!(preloads: [posts: :author])
|> Enum.map(&{&1.name, length(&1.posts)})
#=> [{"Ann", 2}, {"Bob", 1}]
Joining a has_many repeats each parent row once per child. To keep :page and :distinct counting parents, BoxTurtle applies them in a primary-key subquery when a to-many association is preloaded, still in the same statement. Preloads accept association names only, not preload queries or functions.
Pagination
page: n returns page n of :page_size rows (default 40; set page_size: in use BoxTurtle.Schema.Query to change it). page: [number: n, size: s] sets the size per call. Pages below 1 are treated as 1.
Post.Query.list!(sort: [:popularity], page: [number: 1, size: 2]) |> Enum.map(& &1.title)
#=> ["Second post", "Bob's news"]

Post.Query.list!(sort: [:popularity], page: [number: 2, size: 2]) |> Enum.map(& &1.title)
#=> ["Hello"]
Always page with a sort that ends in a unique column, so rows don't move between pages.
More filter and sort examples
The repository has reference filter and sort modules with tests that use them:
test/support/examples/schema.ex,
custom_filters_test.exs
and custom_sort_test.exs. They cover:
	Open modules (use BoxTurtle.Schema.Filters / Sort):	comparisons, LIKE search with escaping, flags that expand to other filters;
	overriding a real column for one value;
	filters and sorts on a joined association, sharing one named join;
	filtering parents by their children with a subquery.


	Closed modules that implement the behaviour directly. They accept only allow-listed, string-keyed request params, and everything else raises.

5. Scoped queries: extend and delegate
The optional *_by(pattern, opts \\ []) functions (get_by, list_by, count_by, query_by! and their ! variants) answer questions like "the posts of this author".
	extend/2 defines one of them with your own clauses. It generates the function head with the opts \\ [] default. For list_by, count_by and query_by! (and their variants), it also adds a clause that treats a nil pattern as "everything".
	delegate/1 defines them by forwarding to a shared delegate module. Use it when many schemas are scoped the same way (every row with an author_id, say).

Write the scope once, in a delegate module. It is an ordinary Query module whose clauses use extend/2:
defmodule MyApp.Blog.ByAuthor do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, schema: MyApp.Blog.Author

  extend :list_by do
    def list_by(%MyApp.Blog.Author{id: id}, opts), do: list(add_filters(opts, author_id: id))
  end

  extend :count_by do
    def count_by(%MyApp.Blog.Author{id: id}, opts), do: count(add_filters(opts, author_id: id))
  end
end
Then delegate to it from each schema's Query module, and add your own clauses with extend/2. This is the final Post.Query:
defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query,
    repo: MyApp.Repo,
    default_sort: [desc: :inserted_at, desc: :id],
    filter_module: MyApp.Blog.Post.Filters,
    sorting_module: MyApp.Blog.Post.Sort,
    delegates: [{MyApp.Blog.ByAuthor, %MyApp.Blog.Author{}}]

  # list_by/2 and count_by/2 for %Author{} (and nil) patterns
  delegate [:list_by, :count_by]

  # get_by!/2 for a title
  extend :get_by! do
    def get_by!(title, opts) when is_binary(title), do: get!(%{title: title}, opts)
  end
end
{:ok, posts} = Post.Query.list_by(ann)
Enum.map(posts, & &1.title)   #=> ["Second post", "Hello"]

{:ok, 1} = Post.Query.count_by(ann, filters: [status: "published"])
{:ok, 2} = Post.Query.count_by(ann, filters: [min_likes: 0])   # custom filters work in delegates too
{:ok, all_posts} = Post.Query.list_by(nil)                     # nil means unscoped
3 = length(all_posts)

%Post{likes: 5} = Post.Query.get_by!("Bob's news")
Post.Query passes %Author{} arguments to ByAuthor with its own settings (repo, schema, default sort, filter module and so on) injected into the options. So ByAuthor.list/1 queries posts, not authors. A delegate clause is generated only if the delegate module defines that function. That check happens at compile time, so the delegate must compile first. Mix handles this when the delegate is in its own file; within a single file, define the delegate above the modules that use it.
6. KSUID primary keys
defmodule MyApp.Blog.Tag do
  use Ecto.Schema
  import Ecto.Changeset

  @primary_key {:id, BoxTurtle.Schema.Ecto.Ksuid, autogenerate: true}
  schema "tags" do
    field :name, :string
  end

  def changeset(tag, attrs), do: tag |> cast(attrs, [:name]) |> validate_required([:name])
end

defmodule MyApp.Blog.Tag.Query do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, default_sort: [:name]
end

defmodule MyApp.Blog.Tag.Change do
  use BoxTurtle.Schema.Change, repo: MyApp.Repo
end
# priv/repo/migrations/20260101000001_create_tags.exs
defmodule MyApp.Repo.Migrations.CreateTags do
  use Ecto.Migration

  def change do
    create table(:tags, primary_key: false) do
      add :id, :string, size: 27, primary_key: true
      add :name, :string, null: false
    end
  end
end
{:ok, tag} = MyApp.Blog.Tag.Change.create(%{name: "elixir"})
27 = String.length(tag.id)
{:ok, ^tag} = MyApp.Blog.Tag.Query.get(tag.id)
KSUIDs are 27-character, time-sortable strings.
7. Testing
The generated functions are ordinary module functions, so test them through your context with the Ecto SQL sandbox. With a Phoenix-generated MyApp.DataCase:
defmodule MyApp.BlogTest do
  use MyApp.DataCase, async: true

  alias MyApp.Blog.{Author, Post}

  test "list_by/2 returns only the author's published posts" do
    {:ok, ann} = Author.Change.create(%{name: "Ann"})
    {:ok, bob} = Author.Change.create(%{name: "Bob"})
    {:ok, _} = Post.Change.create(%{title: "Mine", status: "published", author_id: ann.id})
    {:ok, _} = Post.Change.create(%{title: "Draft", author_id: ann.id})
    {:ok, _} = Post.Change.create(%{title: "Theirs", status: "published", author_id: bob.id})

    assert {:ok, [%Post{title: "Mine"}]} = Post.Query.list_by(ann, filters: [status: "published"])
  end
end
BoxTurtle's own suite runs against SQLite (ecto_sqlite3). For a compact setup, see test/support/ in the repository.

A convention-driven data-access layer for Ecto schemas.
For a schema MyApp.Blog.Post, define two sibling modules and let them be the only code that touches the Repo:
defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, default_sort: [desc: :inserted_at]
end

defmodule MyApp.Blog.Post.Change do
  use BoxTurtle.Schema.Change, repo: MyApp.Repo
end

alias MyApp.Blog.Post

{:ok, post} = Post.Change.create(%{title: "Hello"})   # uses Post.changeset/2
[^post] = Post.Query.list!(filters: [title: "Hello"])
1 = Post.Query.count!()
	BoxTurtle.Schema.Query - get, list, count and query! with filters, sorting, pagination,
preloads, grouping and distinct, plus pattern-scoped *_by extensions.
	BoxTurtle.Schema.Change - create, update and delete.
	BoxTurtle.Schema.Filters, BoxTurtle.Schema.Sort - default filtering and sorting, and bases for
schema-specific versions.
	BoxTurtle.Schema.Pagination - limit/offset paging.
	BoxTurtle.Schema.Ecto.Ksuid - a KSUID Ecto.Type.

See the Schema guide for a complete walkthrough.

Generates the write functions of BoxTurtle.Schema.Change.API for an Ecto schema.
Attribute maps go through the schema's changeset functions, so the schema must define them:
changeset/2 by default, for both inserts and updates.
defmodule MyApp.Blog.Post do
  use Ecto.Schema
  import Ecto.Changeset

  schema "posts" do
    field :title, :string
    timestamps()
  end

  def changeset(post, attrs), do: post |> cast(attrs, [:title]) |> validate_required([:title])
end

# delete/1 by primary key looks rows up through the sibling Query module.
defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo
end

defmodule MyApp.Blog.Post.Change do
  use BoxTurtle.Schema.Change, repo: MyApp.Repo
end

alias MyApp.Blog.Post

{:ok, post} = Post.Change.create(%{title: "Hello"})
{:error, %Ecto.Changeset{}} = Post.Change.create(%{title: nil})
{:ok, post} = Post.Change.update(post, %{title: "Hello again"})
{:ok, _deleted} = Post.Change.delete(post.id)
{:error, :not_found} = Post.Change.delete(post.id)
Options
	:repo - the Ecto.Repo to write to. Required.
	:schema - the schema module. Defaults to the parent of the using module (MyApp.Blog.Post above).
	:query - the BoxTurtle.Schema.Query module used to look rows up by key in delete/1.
Defaults to <schema>.Query.
	:create_changeset - name of the schema's fun(struct, attrs) used by create. Defaults to :changeset.
	:update_changeset - name of the schema's fun(struct, attrs) used by update. Defaults to :changeset.
	:create_opts - options passed to Ecto.Repo.insert/2, e.g. [on_conflict: :nothing].


      




  

    
BoxTurtle.Schema.Change.API behaviour
    



      
Write operations generated by use BoxTurtle.Schema.Change: create, update and delete.
The counterpart to BoxTurtle.Schema.Query.API, with the idea that nothing outside a Query or Change module
touches the Repo. Plain functions return {:ok, struct} / {:error, changeset} like Ecto.Repo; !
functions return the struct or raise.

        Inserts a changeset, or a changeset built from a map (or struct) of attributes.

        delete(arg1)

      


        Deletes a struct, a changeset, or the row with the given primary key ({:error, :not_found} if absent).

        Updates a changeset, or a struct with a map of changes.

          @callback create(attrs() | Ecto.Changeset.t()) ::
  {:ok, schema()} | {:error, Ecto.Changeset.t()}


      


Inserts a changeset, or a changeset built from a map (or struct) of attributes.

          @callback delete(key() | schema() | Ecto.Changeset.t()) ::
  {:ok, schema()} | {:error, Ecto.Changeset.t() | :not_found}


      


Deletes a struct, a changeset, or the row with the given primary key ({:error, :not_found} if absent).

          @callback update(Ecto.Changeset.t()) :: {:ok, schema()} | {:error, Ecto.Changeset.t()}


      


Updates a changeset, or a struct with a map of changes.

An Ecto.Type for KSUID keys, stored as 27-character base62 strings.
KSUIDs sort by creation time, which makes them convenient primary keys.
defmodule MyApp.Blog.Tag do
  use Ecto.Schema

  # Generated on insert; @foreign_key_type makes belongs_to fields KSUIDs too.
  @primary_key {:id, BoxTurtle.Schema.Ecto.Ksuid, autogenerate: true}
  @foreign_key_type BoxTurtle.Schema.Ecto.Ksuid

  schema "tags" do
    field :name, :string
  end
end

# The migration stores the key as a string column.
defmodule MyApp.Repo.Migrations.CreateTags do
  use Ecto.Migration

  def change do
    create table(:tags, primary_key: false) do
      add :id, :string, size: 27, primary_key: true
      add :name, :string, null: false
    end
  end
end

{:ok, tag} = MyApp.Repo.insert(%MyApp.Blog.Tag{name: "elixir"})
tag.id #=> "2Ux8k3WmS1mXJ9i1QeB6LcPq0Zf"

        True for a 27-character base62 string.

          @spec valid?(term()) :: boolean()


      


True for a 27-character base62 string.

Default filtering for BoxTurtle.Schema.Query, and a base for schema-specific filter modules.
Each filter is a {column, value} pair, combined with AND:
	{:status, "active"} - status = 'active'
	{:status, ["active", "pending"]} - status IN (...)
	{:deleted_at, nil} - deleted_at IS NULL

String column names are accepted, but only if the atom already exists (String.to_existing_atom/1), so
filters built from request params can't create atoms.
Custom filters
Use this module and add filter_with/2 clauses for named filters that aren't plain column comparisons.
Each clause matches the filter at the head of the list and must pass the rest back to filter_with/2.
Filters your clauses don't match fall through to the default behaviour, one filter at a time.
For a MyApp.Blog.Post schema with likes and published_at fields:
defmodule MyApp.Blog.Post.Filters do
  use BoxTurtle.Schema.Filters
  import Ecto.Query

  def filter_with(query, [{:published_after, %DateTime{} = date} | rest]) do
    query
    |> where([p], p.published_at > ^date)
    |> filter_with(rest)
  end

  def filter_with(query, [{:min_likes, likes} | rest]) do
    query
    |> where([p], p.likes >= ^likes)
    |> filter_with(rest)
  end
end

defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, filter_module: MyApp.Blog.Post.Filters
end

# Custom and plain column filters mix freely, in any order.
last_week = DateTime.add(DateTime.utc_now(), -7, :day)
MyApp.Blog.Post.Query.list!(filters: [published_after: last_week, status: "published", min_likes: 10])
Custom clauses see keys exactly as given, so match atoms and convert request params yourself.
For more patterns (joins, subqueries, and closed allow-list modules for request params), see the
reference modules in the repository's test/support/examples/schema.ex.

        Applies a single {column, value} filter (see the module documentation) to the query.

          @spec apply_filter(Ecto.Queryable.t(), {atom() | String.t(), term()}) ::
  Ecto.Queryable.t()


      


Applies a single {column, value} filter (see the module documentation) to the query.

  


        

      


  

    
BoxTurtle.Schema.Filters.API behaviour
    



      
Behaviour for modules that turn a list of filters into where clauses.
See BoxTurtle.Schema.Filters for the default behaviour.

        A list of {column_or_filter_name, value} pairs.

A list of {column_or_filter_name, value} pairs.

BoxTurtle.Schema.Pagination 
    



      
Limit/offset pagination for Ecto queries.
BoxTurtle.Schema.Query applies it for the :page option, so you rarely call it directly. It also
works on any Ecto query. A page is either a page number, using the default size, or a keyword list:
import Ecto.Query
alias BoxTurtle.Schema.Pagination

query = from(p in MyApp.Blog.Post, order_by: [desc: p.inserted_at, desc: p.id])

# Second page of 40 rows (the default size): LIMIT 40 OFFSET 40
query |> Pagination.page(2) |> MyApp.Repo.all()

# Rows 11-20: LIMIT 10 OFFSET 10
query |> Pagination.page(number: 2, size: 10) |> MyApp.Repo.all()
Page numbers below 1 are treated as 1. Give the query an order_by ending in a unique column,
so rows don't move between pages.

        A page number, or [number: pos_integer(), size: pos_integer()].

        The page size used when none is configured: 40.

        Applies limit/offset for the given page to the query. A nil page leaves the query untouched.

          @type page_spec() :: nil | pos_integer() | keyword()


      


A page number, or [number: pos_integer(), size: pos_integer()].

The page size used when none is configured: 40.

          @spec page(Ecto.Queryable.t(), page_spec(), pos_integer()) :: Ecto.Queryable.t()


      


Applies limit/offset for the given page to the query. A nil page leaves the query untouched.

  


        

      


  

    
BoxTurtle.Schema.Query 
    



      
Generates the standard read functions of BoxTurtle.Schema.Query.API for an Ecto schema.
Given an Ecto schema MyApp.Blog.Post (with title, status, timestamps, and
belongs_to :author, MyApp.Blog.Author), define a sibling module:
defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query,
    repo: MyApp.Repo,
    default_sort: [desc: :inserted_at, desc: :id],
    default_preloads: [:author]
end
and call it from your context:
defmodule MyApp.Blog do
  alias MyApp.Blog.Post

  # Second page of published posts, newest first, each with its author (one query).
  def published_posts(page), do: Post.Query.list!(filters: [status: "published"], page: page)

  # [%{status: "draft", count: 3}, %{status: "published", count: 12}]
  def post_counts_by_status, do: Post.Query.count!(group_by: [:status])

  # {:ok, %Post{}} or {:error, :not_found}
  def fetch_post(id), do: Post.Query.get(id)
end
See BoxTurtle.Schema.Query.API for the generated functions and their call-time options, and the
Schema guide for a walkthrough.
Options
	:repo - the Ecto.Repo to query. Required.
	:schema - the schema module. Defaults to the parent of the using module (MyApp.Blog.Post above).
	:primary_key - defaults to :id.
	:default_sort - sort applied to lists unless overridden. Defaults to [primary_key].
	:default_preloads - associations to preload. Defaults to [].
	:default_distinct - columns for DISTINCT ON (PostgreSQL only: with other adapters the module
fails to compile). Defaults to [].
	:filter_module - a BoxTurtle.Schema.Filters.API implementation. Defaults to BoxTurtle.Schema.Filters.
	:sorting_module - a BoxTurtle.Schema.Sort.API implementation. Defaults to BoxTurtle.Schema.Sort.
	:page_size - rows per page when :page is a number. Defaults to 40.
	:delegates - [{DelegateModule, %Pattern{}}], see delegate/1.
	:ownership_scope - module passed to delegates as :row_module. Defaults to each delegate module.

Extensions
extend/2 and delegate/1 generate the optional *_by(pattern, opts \\ []) functions. Each one gets:
	a clause per :delegates entry whose module implements the function, forwarding %Pattern{} arguments
to it with this module's settings injected into the options, so the delegate queries this schema;
	for count_by, list_by and query_by! (and their variants), a nil clause that falls back to the
unscoped count, list or query!;
	with extend/2, your own clauses.

A delegate holds a scope shared by several schemas, here "rows belonging to an author". It is an
ordinary Query module; when called through a delegating module, list/1 and count/1 run
against the delegating module's schema:
defmodule MyApp.Blog.ByAuthor do
  use BoxTurtle.Schema.Query, repo: MyApp.Repo, schema: MyApp.Blog.Author

  extend :list_by do
    def list_by(%MyApp.Blog.Author{id: id}, opts), do: list(add_filters(opts, author_id: id))
  end

  extend :count_by do
    def count_by(%MyApp.Blog.Author{id: id}, opts), do: count(add_filters(opts, author_id: id))
  end
end

defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query,
    repo: MyApp.Repo,
    delegates: [{MyApp.Blog.ByAuthor, %MyApp.Blog.Author{}}]

  # list_by/2 and count_by/2 for %Author{} patterns (and nil), from the delegate.
  delegate [:list_by, :count_by]

  # Your own clauses (posts here have a :slug column).
  extend :get_by! do
    def get_by!(slug, opts) when is_binary(slug), do: get!(%{slug: slug}, opts)
  end
end

author = MyApp.Repo.get!(MyApp.Blog.Author, author_id)
{:ok, posts} = MyApp.Blog.Post.Query.list_by(author, filters: [status: "published"])
{:ok, all_posts} = MyApp.Blog.Post.Query.list_by(nil)
post = MyApp.Blog.Post.Query.get_by!("hello-world")

and nil clauses, followed by the clauses in block.

Defines the extension function extension (one of [:count_by, :count_by!, :get_by, :get_by!, :list_by, :list_by!, :query_by!]) with its delegate
and nil clauses, followed by the clauses in block.

  


        

      


  

    
BoxTurtle.Schema.Query.API behaviour
    



      
Read operations generated by use BoxTurtle.Schema.Query.
Functions come in pairs: the plain form returns {:ok, result} / {:error, reason}, the ! form returns the
result directly (nil when get!/2 finds nothing).
Call-time options
	:filters - keyword list of filters, see BoxTurtle.Schema.Filters
	:sort - sort specification, see BoxTurtle.Schema.Sort
	:page - page number or [number: n, size: s], see BoxTurtle.Schema.Pagination
	:preloads - associations to preload, nested to any depth ([:author, comments: :user]). They are
LEFT JOINed and loaded in the same query, see BoxTurtle.Schema.Query.Helpers.preloads/3.
Ignored by aggregates
	:distinct - columns for DISTINCT ON (PostgreSQL only); a count uses the first one as
COUNT(DISTINCT column), which works on every database
	:group_by - columns to group by; count then returns a list of maps
	:aggregate - :count (used internally by count/1)
	:ignore_defaults - when true, the module's default sort, preloads and distinct are not applied
	:query_opts - options passed to Ecto.Repo.all/2 by list/1

Any use-time setting (:repo, :schema, :default_sort, ...) can also be overridden per call; see
BoxTurtle.Schema.Query.Options.API.
Extension functions
The *_by callbacks are optional. They are generated with BoxTurtle.Schema.Query.extend/2 and
BoxTurtle.Schema.Query.delegate/1, which scope a query by a pattern (e.g. "all posts of this %Author{}").

        Counts rows, or rows per group when :group_by is given.

        Counts rows scoped by a pattern. A nil pattern counts everything.

        Fetches a row by primary key (or by a map of key columns). {:error, :not_found} when absent.

        Fetches the row identified by a pattern.

        Lists rows scoped by a pattern. A nil pattern lists everything.

        Applies the options (sort, filters, paging, preloads or aggregation) to an existing queryable.

        Builds a query on the schema from the options, without running it.

        Builds a query scoped by a pattern.

          @callback count() :: {:ok, integer() | [map()]}


      


Counts rows, or rows per group when :group_by is given.

          @callback count(opts()) :: {:ok, integer() | [map()]}

          @callback count_by(pattern :: term()) :: {:ok, integer() | [map()]} | {:error, term()}


      


Counts rows scoped by a pattern. A nil pattern counts everything.

  {:ok, integer() | [map()]} | {:error, term()}


      



  



  
    
      
    
    
      count_by!(pattern)


        (optional)


        
          
        

    

  


  

      

          @callback count_by!(pattern :: term()) :: integer() | [map()]

          @callback get(key :: term()) :: {:ok, schema()} | {:error, :not_found}


      


Fetches a row by primary key (or by a map of key columns). {:error, :not_found} when absent.

          @callback get_by(pattern :: term()) :: {:ok, schema()} | {:error, term()}


      


Fetches the row identified by a pattern.

          @callback get_by(pattern :: term(), opts()) :: {:ok, schema()} | {:error, term()}


      



  



  
    
      
    
    
      get_by!(pattern)


        (optional)


        
          
        

    

  


  

      

          @callback get_by!(pattern :: term()) :: schema() | nil


      



  



  
    
      
    
    
      get_by!(pattern, opts)


        (optional)


        
          
        

    

  


  

      

          @callback get_by!(pattern :: term(), opts()) :: schema() | nil


      



  



  
    
      
    
    
      list()



        
          
        

    

  


  

      

          @callback list() :: {:ok, [schema()]}


      


Lists rows.

  



  
    
      
    
    
      list(opts)



        
          
        

    

  


  

      

          @callback list(opts()) :: {:ok, [schema()]}


      



  



  
    
      
    
    
      list!()



        
          
        

    

  


  

      

          @callback list!() :: [schema()]


      



  



  
    
      
    
    
      list!(opts)



        
          
        

    

  


  

      

          @callback list!(opts()) :: [schema()]


      



  



  
    
      
    
    
      list_by(pattern)


        (optional)


        
          
        

    

  


  

      

          @callback list_by(pattern :: term()) :: {:ok, [schema()]} | {:error, term()}


      


Lists rows scoped by a pattern. A nil pattern lists everything.

  



  
    
      
    
    
      list_by(pattern, opts)


        (optional)


        
          
        

    

  


  

      

          @callback list_by(pattern :: term(), opts()) :: {:ok, [schema()]} | {:error, term()}


      



  



  
    
      
    
    
      list_by!(pattern)


        (optional)


        
          
        

    

  


  

      

          @callback list_by!(pattern :: term()) :: [schema()]


      



  



  
    
      
    
    
      list_by!(pattern, opts)


        (optional)


        
          
        

    

  


  

      

          @callback list_by!(pattern :: term(), opts()) :: [schema()]


      



  



  
    
      
    
    
      pipe_query!(t)



        
          
        

    

  


  

      

          @callback pipe_query!(Ecto.Queryable.t()) :: Ecto.Queryable.t()


      


Applies the options (sort, filters, paging, preloads or aggregation) to an existing queryable.

  



  
    
      
    
    
      pipe_query!(t, opts)



        
          
        

    

  


  

      

          @callback pipe_query!(Ecto.Queryable.t(), opts()) :: Ecto.Queryable.t()


      



  



  
    
      
    
    
      query!()



        
          
        

    

  


  

      

          @callback query!() :: Ecto.Queryable.t()


      


Builds a query on the schema from the options, without running it.

  



  
    
      
    
    
      query!(opts)



        
          
        

    

  


  

      

          @callback query!(opts()) :: Ecto.Queryable.t()


      



  



  
    
      
    
    
      query_by!(pattern)


        (optional)


        
          
        

    

  


  

      

          @callback query_by!(pattern :: term()) :: Ecto.Queryable.t()


      


Builds a query scoped by a pattern.

  



  
    
      
    
    
      query_by!(pattern, opts)


        (optional)


        
          
        

    

  


  

      

          @callback query_by!(pattern :: term(), opts()) :: Ecto.Queryable.t()


      



  


        

      


  

    
BoxTurtle.Schema.Query.Helpers 
    



      
Option handling and query assembly used by the functions BoxTurtle.Schema.Query generates.
Public so custom query extensions can reuse them; add_filters/2 in particular is handy for adding
filters to the options an extension receives.

      


      
        Summary


  
    Functions
  


    
      
        add_filters(opts, filters)

      


        Merges filters into the :filters already present in opts.



    


    
      
        aggregate?(opts)

      


        True when the options request an aggregate (e.g. a count).



    


    
      
        aggregate_distinction(opts, default_distinct \\ [])

      


        The columns to count distinctly in an aggregate (sort directions dropped).



    


    
      
        aggregate_query!(query, atom, filter_module, opts)

      


        Builds an aggregate query. Only :count is supported.



    


    
      
        aggregate_result!(query, atom, grouping, repo, opts)

      


        Runs an aggregate query: a single integer without grouping, otherwise a list of maps holding the grouped
columns and :count.



    


    
      
        aggregation(opts)

      


        The :aggregate option, or nil.



    


    
      
        build_listings!(query, sorting_module, default_sort, opts, page_size \\ default_page_size())

      


        Applies sorting and pagination.



    


    
      
        build_query!(query, filter_module, opts \\ [])

      


        Applies grouping and filters.



    


    
      
        distinct_on!(columns, repo)

      


        Returns the :distinct columns unchanged if repo's adapter supports DISTINCT ON, and raises
ArgumentError if it is known not to (SQLite3, MyXQL, Tds). The adapter would otherwise only fail
once the query runs.



    


    
      
        get_opt(opts, option, module_default, no_default_value)

      


        Fetches a call-time option, falling back to module_default, or to no_default_value when the
ignore_defaults: true option is set.



    


    
      
        group(query, column)

      


        Adds group_by clauses. String column names must already exist as atoms.



    


    
      
        grouping(opts)

      


        The :group_by columns.



    


    
      
        ignore_defaults?(opts)

      


        True when the ignore_defaults: true option is set.



    


    
      
        joining(default_preloads, opts)

      


        The associations to preload.



    


    
      
        paging(opts)

      


        The :page option (see BoxTurtle.Schema.Pagination).



    


    
      
        preloads(query, assocs, primary_key \\ :id)

      


        Preloads associations through LEFT JOINs, so rows and their associations come back from the
database in a single query instead of one extra query per association.



    


    
      
        query_distinction(opts, default_distinct \\ [])

      


        The :distinct columns for list queries.



    


    
      
        sorting(default_sort, opts)

      


        The sort specification.



    


    
      
        unique(query, columns)

      


        Adds a distinct clause.



    


    
      
        where_key(query, key, primary_key)

      


        Restricts the query to one key: a single value for primary_key, or a map/keyword list of
column values for composite keys.



    





      


      
        Functions


        


  
    
      
    
    
      add_filters(opts, filters)



        
          
        

    

  


  

      

          @spec add_filters(keyword(), keyword()) :: keyword()


      


Merges filters into the :filters already present in opts.

  



  
    
      
    
    
      aggregate?(opts)



        
          
        

    

  


  

      

          @spec aggregate?(keyword()) :: boolean()


      


True when the options request an aggregate (e.g. a count).

  



    

  
    
      
    
    
      aggregate_distinction(opts, default_distinct \\ [])



        
          
        

    

  


  

      

          @spec aggregate_distinction(keyword(), list()) :: [atom()]


      


The columns to count distinctly in an aggregate (sort directions dropped).

  



  
    
      
    
    
      aggregate_query!(query, atom, filter_module, opts)



        
          
        

    

  


  

      

          @spec aggregate_query!(Ecto.Queryable.t(), :count, module(), keyword()) ::
  Ecto.Query.t()


      


Builds an aggregate query. Only :count is supported.

  



  
    
      
    
    
      aggregate_result!(query, atom, grouping, repo, opts)



        
          
        

    

  


  

      

          @spec aggregate_result!(Ecto.Queryable.t(), :count, [atom()], module(), keyword()) ::
  integer() | [map()]


      


Runs an aggregate query: a single integer without grouping, otherwise a list of maps holding the grouped
columns and :count.

  



  
    
      
    
    
      aggregation(opts)



        
          
        

    

  


  

      

          @spec aggregation(keyword()) :: atom() | nil


      


The :aggregate option, or nil.

  



    

  
    
      
    
    
      build_listings!(query, sorting_module, default_sort, opts, page_size \\ default_page_size())



        
          
        

    

  


  

      

          @spec build_listings!(Ecto.Queryable.t(), module(), list(), keyword(), pos_integer()) ::
  Ecto.Queryable.t()


      


Applies sorting and pagination.

  



    

  
    
      
    
    
      build_query!(query, filter_module, opts \\ [])



        
          
        

    

  


  

      

          @spec build_query!(Ecto.Queryable.t(), module(), keyword()) :: Ecto.Queryable.t()


      


Applies grouping and filters.

  



  
    
      
    
    
      distinct_on!(columns, repo)



        
          
        

    

  


  

      

          @spec distinct_on!(list(), module()) :: list()


      


Returns the :distinct columns unchanged if repo's adapter supports DISTINCT ON, and raises
ArgumentError if it is known not to (SQLite3, MyXQL, Tds). The adapter would otherwise only fail
once the query runs.
Counts are not affected: count(distinct: ...) uses COUNT(DISTINCT column), which every adapter supports.

  



  
    
      
    
    
      get_opt(opts, option, module_default, no_default_value)



        
          
        

    

  


  

      

          @spec get_opt(keyword(), atom(), any(), any()) :: any()


      


Fetches a call-time option, falling back to module_default, or to no_default_value when the
ignore_defaults: true option is set.

  



  
    
      
    
    
      group(query, column)



        
          
        

    

  


  

      

          @spec group(Ecto.Queryable.t(), nil | atom() | String.t() | [atom() | String.t()]) ::
  Ecto.Queryable.t()


      


Adds group_by clauses. String column names must already exist as atoms.

  



  
    
      
    
    
      grouping(opts)



        
          
        

    

  


  

      

          @spec grouping(keyword()) :: list()


      


The :group_by columns.

  



  
    
      
    
    
      ignore_defaults?(opts)



        
          
        

    

  


  

      

          @spec ignore_defaults?(keyword()) :: boolean()


      


True when the ignore_defaults: true option is set.

  



  
    
      
    
    
      joining(default_preloads, opts)



        
          
        

    

  


  

      

          @spec joining(list(), keyword()) :: list()


      


The associations to preload.

  



  
    
      
    
    
      paging(opts)



        
          
        

    

  


  

      

          @spec paging(keyword()) :: BoxTurtle.Schema.Pagination.page_spec()


      


The :page option (see BoxTurtle.Schema.Pagination).

  



    

  
    
      
    
    
      preloads(query, assocs, primary_key \\ :id)



        
          
        

    

  


  

      

          @spec preloads(Ecto.Queryable.t(), nil | atom() | list(), atom()) ::
  Ecto.Queryable.t()


      


Preloads associations through LEFT JOINs, so rows and their associations come back from the
database in a single query instead of one extra query per association.
assocs takes the usual preload shapes, nested to any depth: :author, [:author, :tags],
[author: [:company], comments: :user]. Duplicates are merged.
Joining a to-many association repeats each parent row once per child, so LIMIT, OFFSET and
DISTINCT would count child rows. When the query has any of them, they are applied in a subquery
selecting primary_key, and the joins are made against that selection.

  



    

  
    
      
    
    
      query_distinction(opts, default_distinct \\ [])



        
          
        

    

  


  

      

          @spec query_distinction(keyword(), list()) :: list()


      


The :distinct columns for list queries.

  



  
    
      
    
    
      sorting(default_sort, opts)



        
          
        

    

  


  

      

          @spec sorting(list(), keyword()) :: list()


      


The sort specification.

  



  
    
      
    
    
      unique(query, columns)



        
          
        

    

  


  

      

          @spec unique(Ecto.Queryable.t(), nil | atom() | list()) :: Ecto.Queryable.t()


      


Adds a distinct clause.

  



  
    
      
    
    
      where_key(query, key, primary_key)



        
          
        

    

  


  

      

          @spec where_key(Ecto.Queryable.t(), term(), atom()) :: Ecto.Query.t()


      


Restricts the query to one key: a single value for primary_key, or a map/keyword list of
column values for composite keys.

  


        

      


  

    
BoxTurtle.Schema.Query.Options.API behaviour
    



      
Accessors for the settings given to use BoxTurtle.Schema.Query.
Every accessor takes an optional keyword list; a value for the same key in it overrides the use-time setting.
This is how call-time options such as repo: or default_sort: take effect.

      


      
        Summary


  
    Callbacks
  


    
      
        default_distinct()

      


    


    
      
        default_distinct(keyword)

      


    


    
      
        default_preloads()

      


    


    
      
        default_preloads(keyword)

      


    


    
      
        default_sort()

      


    


    
      
        default_sort(keyword)

      


    


    
      
        filter_module()

      


    


    
      
        filter_module(keyword)

      


    


    
      
        inject_query_options(keyword)

      


        Adds every use-time setting to the given options, keeping any value already present in them.



    


    
      
        page_size()

      


    


    
      
        page_size(keyword)

      


    


    
      
        primary_key()

      


    


    
      
        primary_key(keyword)

      


    


    
      
        repo()

      


    


    
      
        repo(keyword)

      


    


    
      
        schema()

      


    


    
      
        schema(keyword)

      


    


    
      
        sorting_module()

      


    


    
      
        sorting_module(keyword)

      


    





      


      
        Callbacks


        


  
    
      
    
    
      default_distinct()



        
          
        

    

  


  

      

          @callback default_distinct() :: [atom()]


      



  



  
    
      
    
    
      default_distinct(keyword)



        
          
        

    

  


  

      

          @callback default_distinct(keyword()) :: [atom()]


      



  



  
    
      
    
    
      default_preloads()



        
          
        

    

  


  

      

          @callback default_preloads() :: list()


      



  



  
    
      
    
    
      default_preloads(keyword)



        
          
        

    

  


  

      

          @callback default_preloads(keyword()) :: list()


      



  



  
    
      
    
    
      default_sort()



        
          
        

    

  


  

      

          @callback default_sort() :: BoxTurtle.Schema.Sort.API.sort_spec()


      



  



  
    
      
    
    
      default_sort(keyword)



        
          
        

    

  


  

      

          @callback default_sort(keyword()) :: BoxTurtle.Schema.Sort.API.sort_spec()


      



  



  
    
      
    
    
      filter_module()



        
          
        

    

  


  

      

          @callback filter_module() :: module()


      



  



  
    
      
    
    
      filter_module(keyword)



        
          
        

    

  


  

      

          @callback filter_module(keyword()) :: module()


      



  



  
    
      
    
    
      inject_query_options(keyword)



        
          
        

    

  


  

      

          @callback inject_query_options(keyword()) :: keyword()


      


Adds every use-time setting to the given options, keeping any value already present in them.

  



  
    
      
    
    
      page_size()



        
          
        

    

  


  

      

          @callback page_size() :: pos_integer()


      



  



  
    
      
    
    
      page_size(keyword)



        
          
        

    

  


  

      

          @callback page_size(keyword()) :: pos_integer()


      



  



  
    
      
    
    
      primary_key()



        
          
        

    

  


  

      

          @callback primary_key() :: atom()


      



  



  
    
      
    
    
      primary_key(keyword)



        
          
        

    

  


  

      

          @callback primary_key(keyword()) :: atom()


      



  



  
    
      
    
    
      repo()



        
          
        

    

  


  

      

          @callback repo() :: module()


      



  



  
    
      
    
    
      repo(keyword)



        
          
        

    

  


  

      

          @callback repo(keyword()) :: module()


      



  



  
    
      
    
    
      schema()



        
          
        

    

  


  

      

          @callback schema() :: module()


      



  



  
    
      
    
    
      schema(keyword)



        
          
        

    

  


  

      

          @callback schema(keyword()) :: module()


      



  



  
    
      
    
    
      sorting_module()



        
          
        

    

  


  

      

          @callback sorting_module() :: module()


      



  



  
    
      
    
    
      sorting_module(keyword)



        
          
        

    

  


  

      

          @callback sorting_module(keyword()) :: module()


      



  


        

      


  

    
BoxTurtle.Schema.Sort 
    



      
Default sorting for BoxTurtle.Schema.Query, and a base for schema-specific sort modules.
A sort specification is a list whose elements are any of:
	:column - ascending order on the column
	{direction, :column} - e.g. {:desc_nulls_last, :reported_at}
	{direction, [:column, ...]} - the same direction for several columns

where direction is one of [:asc, :asc_nulls_first, :asc_nulls_last, :desc, :desc_nulls_first, :desc_nulls_last]
(see Ecto.Query.order_by/3). Keyword lists such as [desc: :inserted_at, asc: :id] therefore work as-is.
Custom sorts
Use this module and add sort_by/2 clauses for named sorts that aren't plain columns. Each clause
handles the element at the head of the list and must pass the rest back to sort_by/2. Elements
your clauses don't match fall through to the default behaviour, one element at a time.
For a MyApp.Blog.Post schema with likes and shares fields:
defmodule MyApp.Blog.Post.Sort do
  use BoxTurtle.Schema.Sort
  import Ecto.Query

  # Most engagement first; the primary key breaks ties so pages are stable.
  def sort_by(query, [:popularity | rest]) do
    query
    |> order_by([p], desc: p.likes + p.shares, asc: p.id)
    |> sort_by(rest)
  end
end

defmodule MyApp.Blog.Post.Query do
  use BoxTurtle.Schema.Query,
    repo: MyApp.Repo,
    sorting_module: MyApp.Blog.Post.Sort,
    default_sort: [:popularity]
end

MyApp.Blog.Post.Query.list!()                                  # most popular first
MyApp.Blog.Post.Query.list!(sort: [desc: :inserted_at, asc: :id]) # plain columns still work
:default_sort goes through your module too, so it may use your named sorts. Sorts on joined
columns and closed modules for ?sort=-likes,title params are shown in the repository's
test/support/examples/schema.ex.

      


      
        Summary


  
    Functions
  


    
      
        apply_sort(query, column)

      


        Applies a single sort element (see the module documentation) to the query.



    





      


      
        Functions


        


  
    
      
    
    
      apply_sort(query, column)



        
          
        

    

  


  

      

          @spec apply_sort(Ecto.Queryable.t(), term()) :: Ecto.Queryable.t()


      


Applies a single sort element (see the module documentation) to the query.
Raises ArgumentError for anything else.

  


        

      


  

    
BoxTurtle.Schema.Sort.API behaviour
    



      
Behaviour for modules that turn a sort specification into order_by clauses.
See BoxTurtle.Schema.Sort for the supported specification forms.

      


      
        Summary


  
    Types
  


    
      
        sort_spec()

      


        A column, {direction, column}, {direction, [column]}, or a list of those.



    





  
    Callbacks
  


    
      
        sort_by(t, sort_spec)

      


    





      


      
        Types


        


  
    
      
    
    
      sort_spec()



        
          
        

    

  


  

      

          @type sort_spec() ::
  atom() | {atom(), atom() | [atom()]} | [atom() | {atom(), atom() | [atom()]}]


      


A column, {direction, column}, {direction, [column]}, or a list of those.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      sort_by(t, sort_spec)



        
          
        

    

  


  

      

          @callback sort_by(Ecto.Queryable.t(), sort_spec()) :: Ecto.Queryable.t()


      



  


        

      


  

    
BoxTurtle.Runtime.Application.Helper 
    



      
Utilities for building an application's supervision tree.
Import the module in your Application and build the children list step by step:
defmodule MyApp.Application do
  use Application

  import BoxTurtle.Runtime.Application.Helper

  @impl true
  def start(_type, _args) do
    children =
      [MyApp.Repo]
      # A boolean, e.g. from config: config :my_app, start_web?: false
      |> conditional_append(Application.get_env(:my_app, :start_web?, true), MyAppWeb.Endpoint)
      # A function, called when the tree is built
      |> conditional_append(&MyApp.Features.workers_enabled?/0, [MyApp.Worker, MyApp.Scheduler])
      # A function with arguments
      |> conditional_append(&Code.ensure_loaded?/1, MyApp.Metrics, [Telemetry.Metrics])

    Supervisor.start_link(children, strategy: :one_for_one, name: MyApp.Supervisor)
  end
end

      


      
        Summary


  
    Types
  


    
      
        condition()

      


        A boolean, or a function returning one when applied to the args list.



    





  
    Functions
  


    
      
        conditional_append(current, condition, conditional, args \\ [])

      


        Appends conditional (a single child or a list of children) to current when condition
holds.



    





      


      
        Types


        


  
    
      
    
    
      condition()



        
          
        

    

  


  

      

          @type condition() :: boolean() | function()


      


A boolean, or a function returning one when applied to the args list.

  


        

      

      
        Functions


        


    

  
    
      
    
    
      conditional_append(current, condition, conditional, args \\ [])



        
          
        

    

  


  

      

          @spec conditional_append(list(), condition(), term(), list()) :: list()


      


Appends conditional (a single child or a list of children) to current when condition
holds.
condition is either a boolean or a function. A function is applied to args
(as with Kernel.apply/2) and must return a boolean.
Examples
iex> conditional_append([:a], true, :b)
[:a, :b]

iex> conditional_append([:a], false, [:b, :c])
[:a]

iex> conditional_append([:a], fn x, y -> x < y end, [:b], [1, 2])
[:a, :b]

  


        

      


  

    
BoxTurtle.Runtime.Config 
    



      
Loads a runtime configuration script (standard import Config syntax, read with Config.Reader) into the
application environment. Combine with BoxTurtle.Runtime.Config.Helper to get properly typed values from
environment variables.
After load_runtime_config/1 runs, the script's settings are read with the usual Application
functions, just like compile-time config. Unlike Mix's own config/runtime.exs, the script can live
anywhere (for example /etc/my_app/settings.exs beside a release) and can be loaded again later.
Usage
	Write the settings script. Give it a name other than config/runtime.exs, which Mix and releases
already load by themselves:
# config/settings.exs
import Config
alias BoxTurtle.Runtime.Config.Helper

config :my_app,
  pool_size: Helper.get_env("POOL_SIZE", type: :integer, default: 10),
  feature_flags: Helper.get_env("FEATURE_FLAGS", type: :list, subtype: :atom, default: [])

	Point each build at its script. Relative paths are resolved from the current working directory:
# config/dev.exs
config :my_app, runtime_config_file: "config/settings.exs"

# config/test.exs
config :my_app, runtime_config_file: "test/support/settings.exs"

# config/prod.exs
config :my_app, runtime_config_file: "/etc/my_app/settings.exs"

	Load it before starting anything that reads those settings:
defmodule MyApp.Application do
  use Application

  @impl true
  def start(_type, _args) do
    :ok = BoxTurtle.Runtime.Config.load_runtime_config(:my_app)

    children = [{MyApp.Pool, size: Application.fetch_env!(:my_app, :pool_size)}]
    Supervisor.start_link(children, strategy: :one_for_one, name: MyApp.Supervisor)
  end
end


Only non-nil values replace existing settings, so an unset environment variable without a
:default keeps the compile-time value.
To load a specific file instead, pass its path: load_runtime_config("/etc/my_app/settings.exs").

      


      
        Summary


  
    Functions
  


    
      
        debug(val, message \\ nil, opts \\ [])

      


        Logs an inspection of the given value, optionally preceded by a message, and returns the value unchanged.
Used to place inspections in the midst of a chain of piped calls.



    


    
      
        load_runtime_config(application)

      


        Load runtime config from environment variables and express them as Application-accessible values.



    





      


      
        Functions


        


    

    

  
    
      
    
    
      debug(val, message \\ nil, opts \\ [])



        
          
        

    

  


  

      

          @spec debug(any(), String.t() | nil, keyword()) :: any()


      


Logs an inspection of the given value, optionally preceded by a message, and returns the value unchanged.
Used to place inspections in the midst of a chain of piped calls.
Nothing is logged unless this module is listed in the application's :debug_enabled_modules setting.
Options
	:condition - a function/1 receiving the value; the message is only logged when it returns true.
Useful for throttling messages in highly repetitive code (log only a given id, a matching name, etc.).

Examples
# Inside a module that does `use BoxTurtle.Debug.PipeDebug` and is listed in
# config :my_app, debug_enabled_modules: [...]
%{jazz: "Art", messenger: "Blakey"}
|> Map.values()
|> debug("Jazz Message")          # logs: Jazz Message: ["Art", "Blakey"]
|> Enum.reverse()                 # returns ["Blakey", "Art"]

  



  
    
      
    
    
      load_runtime_config(application)



        
          
        

    

  


  

      

          @spec load_runtime_config(atom() | String.t()) :: :ok


      


Load runtime config from environment variables and express them as Application-accessible values.
Loading a runtime config will replace existing values set during compile time if given the same names.
Parameters
	application - the Application atom whose runtime configuration is to be set.
OR
	config_path - the path to a runtime script file to parse and load.

Returns
  :ok

  


        

      


  

    
BoxTurtle.Runtime.Config.Helper 
    



      
Reads environment variables and parses them into typed, validated Elixir values, so config files
don't need their own parsing and validation.
Example
# config/runtime.exs
import Config
alias BoxTurtle.Runtime.Config.Helper

config :my_app, MyApp.Repo,
  # "20" -> 20; must be 1..100; 10 when POOL_SIZE is unset
  pool_size: Helper.get_env("POOL_SIZE", type: :integer, default: 10, in_range: 1..100)

config :my_app,
  # "debug" -> :debug; only these existing atoms are accepted
  log_level: Helper.get_env("LOG_LEVEL", type: :atom, in_set: [:debug, :info, :warning], default: :info),
  # "a.example.com, b.example.com" -> ["a.example.com", "b.example.com"]
  hosts: Helper.get_env("HOSTS", type: :list, default: ["localhost"]),
  # "localhost,5432" -> {"localhost", 5432}, one subtype per element
  db_endpoint: Helper.get_env("DB_ENDPOINT", type: :tuple, subtype: {:string, :integer}),
  # ~s({"beta": true}) -> %{"beta" => true}
  features: Helper.get_env("FEATURES", type: :map, default: %{})
An unset variable gives the :default, or nil when there is none. With a validation (:in_set,
:in_range, :regex, :custom) and no :default, an unset variable fails validation, so the
variable is effectively required.
A value that fails to parse or validate is returned as {:error, message}, not raised. Check for it
where a bad value must stop the boot:
case Helper.get_env("PORT", type: :integer, in_range: 1..65_535, default: 4000) do
  {:error, message} -> raise "invalid PORT: #{message}"
  port -> config :my_app, MyAppWeb.Endpoint, http: [port: port]
end
Valid options:
  type:
:atom - The string read from the environment is converted to an atom.
:boolean - The string read from the environment must be in the Elixir set [true, false]
:charlist - The environment variable is converted to an erlang-compatible character list.
:float - The env variable is converted to a float.
:integer - The env variable is converted to an integer.
:module - The env variable is interpreted as an existing (loaded) module name.
:string - The env variable is left as a raw string (elixir binary()).
:list - The env variable is interpreted as a comma-separated list of values of the specified subtype (default: :string)
:tuple - The env variable is interpreted as a comma-separated tuple of values of the specified subtype (default: :string)
:map - The env variable is decoded as a JSON object (with `JSON.decode/1`) into a map with string keys.
  subtype: For lists and tuples, a subtype may be specified indicating the type(s) of elements they are expected to contain.
:atom - the resulting list/tuple will be a set of atoms.
:boolean - the resulting list/tuple will be a set of boolean values.
:charlist - the resulting list/tuple will be a set of charlist elements (list of lists).
:float - the resulting list/tuple will be a set of floating point values.
:integer - the resulting list/tuple will be a set of integers.
:module - the resulting list/tuple will be a set of loaded modules.
:string - the resulting list/tuple will be a set of strings.
:map - the resulting list/tuple will be a set of map() objects.
tuple() - valid only for a type of tuple, the subtype of each element in the tuple can be expressed separately for
  each element in the tuple.  Note that the size of the subtype tuple must be the same as the number of elements
  expressed in the comma-separated values of the environment variable parsed.
list() - the subtype of each element in the tuple or list can be expressed separately for each element in the
  list or tuple.  Note that the size of the subtype list must be the same as the number of elements
  expressed in the comma-separated values of the environment variable parsed.
  default: any() The default value returned when the specified variable is not provided in the system environment.
  in_set: list() The value parsed from the environment variable must be in the specified list of values of the same
type.
  in_range: range() The value parsed from the environment must be within the specified range of values.
  regex: /regex/ pattern the (type: :string) variable must match.
  custom: (tuple(): {Module, validator/2})  A module and function that takes a value and helper options for custom
validation of the value.
  required: (boolean()), when true a value must be provided in the environment.  A nil generates an {:error, msg} result.
  unsafe_atoms: (boolean()), :atom and :module values must name existing atoms unless this is true.  Atoms are never
garbage collected, so only enable it for trusted environments.

      


      
        Summary


  
    Functions
  


    
      
        debug(val, message \\ nil, opts \\ [])

      


        Logs an inspection of the given value, optionally preceded by a message, and returns the value unchanged.
Used to place inspections in the midst of a chain of piped calls.



    


    
      
        get_env(var_name, opts \\ [])

      


        Reads the environment variable var_name, parses it into the requested type and validates it.



    





      


      
        Functions


        


    

    

  
    
      
    
    
      debug(val, message \\ nil, opts \\ [])



        
          
        

    

  


  

      

          @spec debug(any(), String.t() | nil, keyword()) :: any()


      


Logs an inspection of the given value, optionally preceded by a message, and returns the value unchanged.
Used to place inspections in the midst of a chain of piped calls.
Nothing is logged unless this module is listed in the application's :debug_enabled_modules setting.
Options
	:condition - a function/1 receiving the value; the message is only logged when it returns true.
Useful for throttling messages in highly repetitive code (log only a given id, a matching name, etc.).

Examples
# Inside a module that does `use BoxTurtle.Debug.PipeDebug` and is listed in
# config :my_app, debug_enabled_modules: [...]
%{jazz: "Art", messenger: "Blakey"}
|> Map.values()
|> debug("Jazz Message")          # logs: Jazz Message: ["Art", "Blakey"]
|> Enum.reverse()                 # returns ["Blakey", "Art"]

  



    

  
    
      
    
    
      get_env(var_name, opts \\ [])



        
          
        

    

  


  

      

          @spec get_env(binary(), keyword()) :: {:error, binary()} | any()


      


Reads the environment variable var_name, parses it into the requested type and validates it.
Returns the parsed value, the :default (or nil) when the variable is unset, or
{:error, message} when parsing or validation fails. See the module documentation for the options.
Helper.get_env("POOL_SIZE", type: :integer, default: 10, in_range: 1..100)

  


        

      


  

    
BoxTurtle.Runtime.DynamicInterface.ModuleDispatch 
    



      
Generates a module that implements a behaviour by forwarding every callback to an implementation module,
or by generating no-op stubs.
Lets callers depend on a stable facade (MyApp.Mailer) while the implementation (MyApp.Mailer.Impl,
a Mox mock in tests, ...) is chosen by configuration.
Usage
# The contract. It must be compiled before the facade.
defmodule MyApp.Mailer.API do
  @callback deliver(to :: String.t(), subject :: String.t()) :: {:ok, term()} | {:error, term()}
end

# The default implementation, found by the <facade>.Impl naming convention.
defmodule MyApp.Mailer.Impl do
  @behaviour MyApp.Mailer.API

  @impl true
  def deliver(to, subject), do: MyApp.SmtpClient.send(to, subject)
end

# The facade: implements MyApp.Mailer.API by forwarding each call.
defmodule MyApp.Mailer do
  use BoxTurtle.Runtime.DynamicInterface.ModuleDispatch, otp_app: :my_app
end

# Callers only know the facade.
defmodule MyApp.Accounts do
  def send_welcome(user), do: MyApp.Mailer.deliver(user.email, "Welcome!")
end
In tests, point the facade at a Mox mock:
# test/test_helper.exs
Mox.defmock(MyApp.Mailer.Mock, for: MyApp.Mailer.API)

# config/test.exs
config :my_app, MyApp.Mailer, impl: MyApp.Mailer.Mock

# test/my_app/accounts_test.exs
defmodule MyApp.AccountsTest do
  use ExUnit.Case, async: true
  import Mox

  setup :verify_on_exit!

  test "send_welcome/1 mails the user" do
    expect(MyApp.Mailer.Mock, :deliver, fn "ann@example.com", "Welcome!" -> {:ok, :sent} end)
    assert {:ok, :sent} = MyApp.Accounts.send_welcome(%{email: "ann@example.com"})
  end
end
Options
	:behaviour - the behaviour to implement. Defaults to <using module>.API. It must be compiled before
the using module.
	:impl - the default implementation module. Defaults to <using module>.Impl.
	:otp_app - when given, impl_module/0 reads config :otp_app, <using module>, impl: module at runtime,
falling back to :impl.
	:generate_stub - when true, every callback is defined to return :ok instead of forwarding.
Defaults to false. Combine it with Application.compile_env/3 to stub a fire-and-forget
interface out of some builds.

Patterns
Because impl_module/0 reads the configuration on every call, one facade supports:
	per-build implementations - set impl: differently in config/dev.exs, test.exs and prod.exs;
	runtime switching - Application.put_env/3 takes effect on the next call (failover, feature flags);
	Mox - point impl: at Mox.defmock(MyApp.Mailer.Mock, for: MyApp.Mailer.API) in the test
build, and use Mox.stub_with/2 to fall back to a real implementation;
	A/B tests - make the configured implementation a router that implements the same behaviour
and picks a variant per caller.

Worked examples of each, with fake implementations and the tests that use them, are in the
repository: test/support/examples/dispatch.ex and
test/runtime/dynamic_interface/dispatch_examples_test.exs.

      




  

    
BoxTurtle.Debug.PipeDebug 
    



      
Injects a debug/3 function that can be dropped into the middle of a pipe to log a value, returning it unchanged.
Logging is off by default and enabled per module through application configuration, so debug calls can stay in
the code without flooding the logs.
Usage
defmodule MyApp.Billing do
  use BoxTurtle.Debug.PipeDebug

  def invoice_total(items) do
    items
    |> Enum.map(& &1.price)
    |> debug("prices")
    |> Enum.sum()
    # Only log suspicious totals.
    |> debug("large total", condition: &(&1 > 10_000))
  end
end

# config/dev.exs: log from these modules only
config :my_app, debug_enabled_modules: [MyApp.Billing]

# Logger must also let :debug through (the default in dev):
config :logger, level: :debug
With that config, MyApp.Billing.invoice_total([%{price: 5}, %{price: 7}]) returns 12 and logs
prices: [5, 7]. With MyApp.Billing not listed, it returns 12 and logs nothing.
To log at :info instead, or to pick the application whose config is read:
use BoxTurtle.Debug.PipeDebug, application: :my_app, logger_macro: :info
Options
	:application - the application whose :debug_enabled_modules setting is consulted. Defaults to the
application the using module belongs to, falling back to :box_turtle. Useful in tests, where modules
may not belong to a loaded application.
	:logger_module - defaults to Logger. Any module exposing debug/1 and info/1 (functions or macros)
will do; mostly used for testing PipeDebug itself.
	:logger_macro - :debug (default) or :info, the level messages are logged at.


      




  

    
BoxTurtle.Common.IdUtils 
    



      
Small helpers for generating identifiers.
alias BoxTurtle.Common.IdUtils

IdUtils.generate_ksuid()  #=> "2Ux8k3WmS1mXJ9i1QeB6LcPq0Zf" (unique, sortable by time)
IdUtils.generate_uuid()   #=> "5b0e3f4a-8c1d-4d2e-9f6a-1b2c3d4e5f60" (unique, random)
IdUtils.generate_id()     #=> 734_201_558 (NOT unique: test data and labels only)

      


      
        Summary


  
    Functions
  


    
      
        generate_id()

      


        Returns a random integer between 1 and 1,000,000,000.



    


    
      
        generate_ksuid()

      


        Returns a new, time-sortable KSUID string (see BoxTurtle.Schema.Ecto.Ksuid).



    


    
      
        generate_uid()

      


        Same as generate_ksuid/0.



    


    
      
        generate_uuid()

      


        Returns a new random (version 4) UUID string.



    





      


      
        Functions


        


  
    
      
    
    
      generate_id()



        
          
        

    

  


  

      

          @spec generate_id() :: pos_integer()


      


Returns a random integer between 1 and 1,000,000,000.
This is not a unique identifier: values can and will collide once many are generated,
and they are not cryptographically random. Use it for test data or throwaway labels; use
generate_ksuid/0 or generate_uuid/0 for anything that must be unique.

  



  
    
      
    
    
      generate_ksuid()



        
          
        

    

  


  

      

          @spec generate_ksuid() :: String.t()


      


Returns a new, time-sortable KSUID string (see BoxTurtle.Schema.Ecto.Ksuid).

  



  
    
      
    
    
      generate_uid()



        
          
        

    

  


  

      

          @spec generate_uid() :: String.t()


      


Same as generate_ksuid/0.

  



  
    
      
    
    
      generate_uuid()



        
          
        

    

  


  

      

          @spec generate_uuid() :: String.t()


      


Returns a new random (version 4) UUID string.

  


        

      


  

    
BoxTurtle.Common.ReturnOkOr 
    



      
Normalizes loosely-shaped results (nil, bare values, :error, {:error, _}) into {:ok, value} /
{:error, reason} tuples, plus macros that log a message together with the caller's stack trace.
defmodule MyApp.Blog do
  import BoxTurtle.Common.ReturnOkOr

  alias MyApp.Blog.Post
  alias MyApp.Repo

  # Repo.get/2 returns a struct or nil; callers get {:ok, post} or {:error, :not_found}.
  def fetch_post(id), do: Post |> Repo.get(id) |> return_ok_or(:not_found)

  # Map.fetch/2 returns {:ok, value} or :error; normalize :error to a reason.
  def fetch_setting(settings, key), do: settings |> Map.fetch(key) |> return_ok_or(:missing_setting)

  def publish(id) do
    with {:ok, post} <- fetch_post(id) do
      post |> Post.changeset(%{status: "published"}) |> Repo.update()
    end
  end
end

MyApp.Blog.fetch_post(42)                       #=> {:ok, %MyApp.Blog.Post{id: 42}}
MyApp.Blog.fetch_post(-1)                       #=> {:error, :not_found}
MyApp.Blog.fetch_setting(%{theme: "dark"}, :lang) #=> {:error, :missing_setting}

      


      
        Summary


  
    Functions
  


    
      
        error_with_stack(message)

      


        Logs message at :error level with the current stack trace. A macro, so the trace starts at the caller.



    


    
      
        return_error(reason)

      


        Wraps reason in an error tuple.



    


    
      
        return_ok_or(ok)

      


        Passes {:ok, _}, {:error, _} and :error through unchanged.



    


    
      
        return_ok_or(ok, reason)

      


        Returns {:ok, value} for a value or an {:ok, _} tuple, and {:error, reason} for nil, :error or an
{:error, _} tuple (whose own reason is replaced by reason).



    


    
      
        warn_with_stack(message)

      


        Logs message at :warning level with the current stack trace. A macro, so the trace starts at the caller.



    





      


      
        Functions


        


  
    
      
    
    
      error_with_stack(message)


        (macro)


        
          
        

    

  


  

Logs message at :error level with the current stack trace. A macro, so the trace starts at the caller.

  



  
    
      
    
    
      return_error(reason)



        
          
        

    

  


  

      

          @spec return_error(reason) :: {:error, reason} when reason: term()


      


Wraps reason in an error tuple.

  



  
    
      
    
    
      return_ok_or(ok)



        
          
        

    

  


  

      

          @spec return_ok_or({:ok, term()} | {:error, term()} | :error) ::
  {:ok, term()} | {:error, term()} | :error


      


Passes {:ok, _}, {:error, _} and :error through unchanged.

  



  
    
      
    
    
      return_ok_or(ok, reason)



        
          
        

    

  


  

      

          @spec return_ok_or(term(), reason) :: {:ok, term()} | {:error, reason}
when reason: term()


      


Returns {:ok, value} for a value or an {:ok, _} tuple, and {:error, reason} for nil, :error or an
{:error, _} tuple (whose own reason is replaced by reason).

  



  
    
      
    
    
      warn_with_stack(message)


        (macro)


        
          
        

    

  


  

Logs message at :warning level with the current stack trace. A macro, so the trace starts at the caller.

  


        

      


  

    
BoxTurtle.Security.Password 
    



      
Generates random passwords containing at least one lowercase letter, one uppercase letter,
one digit and one special character.
All randomness comes from :crypto.strong_rand_bytes/1 (through :crypto.rand_seed_s/0),
so the passwords are suitable for credentials. The caller's :rand seed is not touched.
alias BoxTurtle.Security.Password

{:ok, password} = Password.generate(16)
String.length(password)  #=> 16
{:error, :too_short} = Password.generate(4)

# e.g. a temporary password for an account created by an admin
def create_invited_user(attrs) do
  {:ok, password} = Password.generate(20)
  attrs |> Map.put(:password, password) |> MyApp.Accounts.register_user()
end
The approach is inspired by the Rosetta Code
Password generator task.

      


      
        Summary


  
    Functions
  


    
      
        generate(length \\ 8)

      


        Generates a random password of length characters (default 8).



    


    
      
        min_length()

      


        Returns the minimum password length accepted by generate/1 (8).



    





      


      
        Functions


        


    

  
    
      
    
    
      generate(length \\ 8)



        
          
        

    

  


  

      

          @spec generate(integer()) :: {:ok, String.t()} | {:error, :too_short}


      


Generates a random password of length characters (default 8).
Returns {:ok, password}, or {:error, :too_short} when length is not an integer of at
least 8.

  



  
    
      
    
    
      min_length()



        
          
        

    

  


  

      

          @spec min_length() :: pos_integer()


      


Returns the minimum password length accepted by generate/1 (8).

